@echo off
if "%1"=="/?" goto HELP

REM ** Emulator Setup **
echo Porable CE 3.0 Setup
echo.

set EMULATORIMG="PPC_USA_GSM_VGA_VR.BIN"
set VMID={C9AAB4F3-5439-4e35-A6FD-5CB22FEC4FFF}
if NOT "%1"=="/clean" goto NETWORKSERVICES
set PORTCEIMG=%EMULATORIMG%
echo [Using Clean Image: %PORTCEIMG%]

:NETWORKSERVICES
echo [Verifying Networks Services]
IF EXIST %SystemRoot%\system32\Drivers\VMNetSrv.sys goto STORAGECARD
echo ** VM Network Services not installed. Installing. **
snetcfg_wxp -v -l "%CD%\VMNetSrv.inf" -c s -i cntx_vpcnets2
SET UNINSTALLDEVICEDRVR=1

:STORAGECARD
set SHAREDIR="%CD%\Apps"
echo .
echo [Emulator Storage Card]
echo [Host Folder: %SHAREDIR%]
echo [In the emulator, use File Explorer to go to "\My Device\Storage Card"]
IF EXIST %SHAREDIR% goto VMDIR
mkdir %SHAREDIR%

:VMDIR
set STATEDIR=State
set STATEFILE="%CD%\%STATEDIR%\StateData.dess"
echo .
echo [Persistent Storage]
echo [Host Folder: %STATEFILE%]
if EXIST "%CD%\%STATEDIR%" goto VMFILE
mkdir "%CD%\%STATEDIR%"

:VMFILE
if EXIST %STATEFILE% goto RUNEMULATOR
set PORTCEIMG=%EMULATORIMG%
echo [Couldn't find state file, using: %PORTCEIMG%]

:RUNEMULATOR
.\DeviceEmulator.exe %PORTCEIMG% /video 640x480x24 /memsize 256 /p /vmname "Portable CE 3.0" /s %STATEFILE% /sharedfolder %SHAREDIR% /vmid %VMID%

:CLEANUP
echo .
if NOT defined UNINSTALLDEVICEDRVR goto FINISH
echo [Cleaning up installed items]
echo ** Uninstalling VM Network Services  **
snetcfg_wxp -u cntx_vpcnets2

:HELP
echo.
echo Portable CE 3.0 Launcher 
echo Syntax: pce3.cmd [/clean]
echo.
echo	/clean	Load a clean copy of the emulator, ignoring saved state files.
echo.
echo.

:FINISH
set PORTCEIMG=
set EMULATORIMG=
set UNINSTALLDEVICEDRVR=
set SHAREDIR=
set STATEDIR=
set STATEFILE=
set VMID=