@echo off
if "%1"=="/?" goto HELP

REM ** Emulator Setup **
echo Porable CE 2.0 Setup
echo.

set EMULATORIMG="%CD%\PPC_2003_SE\PPC_2003_SE_WWE_ARMv4.bin"
set VMID={C9AAB4F3-5439-4e35-A6FD-5CB22FEC4FFF}
if NOT "%1"=="/clean" goto NETWORKSERVICES
set PORTCEIMG=%EMULATORIMG%
echo [Using Clean Image: %PORTCEIMG%]

:NETWORKSERVICES
echo [Verifying Networks Services]
IF EXIST %SystemRoot%\system32\Drivers\VMNetSrv.sys goto STORAGECARD
echo ** VM Network Services not installed. Installing. **
snetcfg_wxp -v -l "%CD%\VMNetSrv.inf" -c s -i cntx_vpcnets2
SET UNINSTALLDEVICEDRVR=1

:STORAGECARD
set SHAREDIR="%CD%\Apps"
echo [Emulator Storage Card enabled. Using: %SHAREDIR%]
echo ** In the emulator, use File Explorer to go to "\My Device\Storage Card" **
IF EXIST %SHAREDIR% goto VMDIR
mkdir %SHAREDIR%

:VMDIR
set STATEDIR=State
set STATEFILE="%CD%\%STATEDIR%\StateData.dess"
echo [Persistent Storage enabled. Using: %STATEFILE%]
if EXIST "%CD%\%STATEDIR%" goto VMFILE
mkdir "%CD%\%STATEDIR%"

:VMFILE
if EXIST %STATEFILE% goto RUNEMULATOR
set PORTCEIMG=%EMULATORIMG%
echo [Couldn't find state file, using: %PORTCEIMG%]

:RUNEMULATOR
.\DeviceEmulator.exe %PORTCEIMG% /video 640x480x16 /memsize 128 /p /vmname "Portable CE 2.0" /s %STATEFILE% /sharedfolder %SHAREDIR% /vmid %VMID%

:CLEANUP
echo .
if NOT defined UNINSTALLDEVICEDRVR goto FINISH
echo [Cleaning up installed items]
echo ** Uninstalling VM Network Services  **
snetcfg_wxp -u cntx_vpcnets2

:HELP
echo.
echo Portable CE 2.0 Emulation Launcher 
echo Syntax: pce2.cmd [/clean]
echo.
echo	/clean	Load a clean copy of the emulator, ignoring saved state files.
echo.
echo.

:FINISH
set PORTCEIMG=
set EMULATORIMG=
set UNINSTALLDEVICEDRVR=
set SHAREDIR=
set STATEDIR=
set STATEFILE=
set VMID=